Category Archives: Maintenance

sp_help_revlogin revisited

I believe I’ve come up with an improvement to sp_help_revlogin.

Transferring a login from one server to another is one of those learning experiences we all go through. If you just do CREATE LOGIN on another server the login in the master database usually gets a different ID. When you restore the database on the other server, the ID of the user in the database doesn’t match the ID of the login in master and so the login can’t access the database. (And, as they say, ‘hilarity ensues’.)

A better way to move the login is to use a Microsoft stored procedure sp_help_revlogin (read more here: http://support.microsoft.com/kb/918992/) to generate a script that will re-create the login with the same ID. But I noticed it doesn’t include the login’s default language, which is something that can have a major impact on things like whether the account can re-use existing cached query plans. So I’ve added this element.

Instead of this:

CREATE LOGIN [loginX]
WITH	PASSWORD = 0x02<snip>9E HASHED
	, SID = 0x8E<snip>80
	, DEFAULT_DATABASE = [databaseY]
	, CHECK_POLICY = ON
	, CHECK_EXPIRATION = OFF

you now get this:

create login [loginX]
with	password = 0x02<snip>9E hashed
	, sid = 0x8E<snip>80
	, default_database = [databaseY]
	, default_language = [us_english]
	, check_policy = on
	, check_expiration = off

(While I was at it, I changed the output to lower case because that’s how I like to code.)

Here’s the new version of the procedure with the altered lines highlighted:

/*
Purpose:	To script out logins for copying to another server.
Source:		http://support.microsoft.com/kb/918992/
Modifications:	I added the default language.
*/

use master;
go

IF OBJECT_ID ('sp_hexadecimal') IS NOT NULL
  DROP PROCEDURE sp_hexadecimal
GO

CREATE PROCEDURE sp_hexadecimal
    @binvalue varbinary(256),
    @hexvalue varchar (514) OUTPUT
AS
DECLARE @charvalue varchar (514)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
SELECT @charvalue = '0x'
SELECT @i = 1
SELECT @length = DATALENGTH (@binvalue)
SELECT @hexstring = '0123456789ABCDEF'
WHILE (@i &amp;amp;lt;= @length)
BEGIN
  DECLARE @tempint int
  DECLARE @firstint int
  DECLARE @secondint int
  SELECT @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
  SELECT @firstint = FLOOR(@tempint/16)
  SELECT @secondint = @tempint - (@firstint*16)
  SELECT @charvalue = @charvalue +
    SUBSTRING(@hexstring, @firstint+1, 1) +
    SUBSTRING(@hexstring, @secondint+1, 1)
  SELECT @i = @i + 1
END

SELECT @hexvalue = @charvalue
GO

IF OBJECT_ID ('sp_help_revlogin') IS NOT NULL
  DROP PROCEDURE sp_help_revlogin
GO
CREATE PROCEDURE sp_help_revlogin @login_name sysname = NULL AS
DECLARE @name sysname
DECLARE @type varchar (1)
DECLARE @hasaccess int
DECLARE @denylogin int
DECLARE @is_disabled int
DECLARE @PWD_varbinary  varbinary (256)
DECLARE @PWD_string  varchar (514)
DECLARE @SID_varbinary varbinary (85)
DECLARE @SID_string varchar (514)
DECLARE @tmpstr  varchar (1024)
DECLARE @is_policy_checked varchar (3)
DECLARE @is_expiration_checked varchar (3)

DECLARE @defaultdb sysname
DECLARE @defaultlanguage sysname

IF (@login_name IS NULL)
  DECLARE login_curs CURSOR FOR

      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, p.default_language_name, l.hasaccess, l.denylogin FROM
sys.server_principals p LEFT JOIN sys.syslogins l
      ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name &amp;amp;lt;&amp;amp;gt; 'sa'
ELSE
  DECLARE login_curs CURSOR FOR

      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, p.default_language_name, l.hasaccess, l.denylogin FROM
sys.server_principals p LEFT JOIN sys.syslogins l
      ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name = @login_name
OPEN login_curs

FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @defaultlanguage, @hasaccess, @denylogin
IF (@@fetch_status = -1)
BEGIN
  PRINT 'No login(s) found.'
  CLOSE login_curs
  DEALLOCATE login_curs
  RETURN -1
END
SET @tmpstr = '/* sp_help_revlogin script '
PRINT @tmpstr
SET @tmpstr = '** Generated ' + CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */'
PRINT @tmpstr
PRINT ''
WHILE (@@fetch_status &amp;amp;lt;&amp;amp;gt; -1)
BEGIN
  IF (@@fetch_status &amp;amp;lt;&amp;amp;gt; -2)
  BEGIN
    PRINT ''
    SET @tmpstr = '-- Login: ' + @name
    PRINT @tmpstr
    IF (@type IN ( 'G', 'U'))
    BEGIN -- NT authenticated account/group

      SET @tmpstr = 'create login ' + QUOTENAME( @name ) + ' from windows with default_database = [' + @defaultdb + '], default_language = [' + @defaultlanguage + ']'
    END
    ELSE BEGIN -- SQL Server authentication
        -- obtain password and sid
            SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS varbinary (256) )
        EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT
        EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT

        -- obtain password policy state
        SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name
        SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name

            SET @tmpstr = 'create login ' + QUOTENAME( @name ) + ' with password = ' + @PWD_string + ' hashed, sid = ' + @SID_string + ', default_database = [' + @defaultdb + '], default_language = [' + @defaultlanguage + ']'

        IF ( @is_policy_checked IS NOT NULL )
        BEGIN
          SET @tmpstr = @tmpstr + ', check_policy = ' + @is_policy_checked
        END
        IF ( @is_expiration_checked IS NOT NULL )
        BEGIN
          SET @tmpstr = @tmpstr + ', check_expiration = ' + @is_expiration_checked
        END
    END
    IF (@denylogin = 1)
    BEGIN -- login is denied access
      SET @tmpstr = @tmpstr + '; deny connect sql to ' + QUOTENAME( @name )
    END
    ELSE IF (@hasaccess = 0)
    BEGIN -- login exists but does not have access
      SET @tmpstr = @tmpstr + '; revoke connect sql to ' + QUOTENAME( @name )
    END
    IF (@is_disabled = 1)
    BEGIN -- login is disabled
      SET @tmpstr = @tmpstr + '; alter login ' + QUOTENAME( @name ) + ' disable'
    END
    PRINT @tmpstr
  END

  FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @defaultlanguage, @hasaccess, @denylogin
   END
CLOSE login_curs
DEALLOCATE login_curs
RETURN 0
GO

You can download the code here.

Advertisements

SQL download file names

When you go to download SQL Server cumulative updates the options can be pretty baffling. Which file(s) do you need? Here’s some help.

For example, if you go to SQL Server 2014 CU1 you are offered these files:

  • Update_SQL2014_RTM_CU1_2931693_12_0_2342_x64
  • 2014_RTM_AOrcleDes_CU1_2931693_12_0_2342_x64
  • 2014_RTM_AOrcleSer_CU1_2931693_12_0_2342_x64

There’s no explanation on the page but presumably it’s explained somewhere. It is, but it’s not easy to find. I asked on the MSDN forum and was pointed to this page which explains it quite clearly.

How to get the logical and physical file names for a database

For some operations you need to know the logical and physical file names for the data and log files in a database. Here’s some code to get hold of this information. It assumes you only have one data and one log file. This is all I have needed so far. I’m sure it could be adapted fairly easily to return a set of file names.

declare @DBName sysname
, @LogicalDataFile sysname
, @LogicalLogFile sysname
, @PhysicalDataFile nvarchar(260)
, @PhysicalLogFile nvarchar(260)

set @DBName = ''

-- Data file
select @LogicalDataFile = name
, @PhysicalDataFile = physical_name
from sys.master_files
where database_id = db_id(@DBName)
and type_desc = 'ROWS'

-- Log file
select @LogicalLogFile = name
, @PhysicalLogFile = physical_name
from sys.master_files
where database_id = db_id(@DBName)
and type_desc = 'LOG'

select @LogicalDataFile as [@LogicalDataFile]
, @LogicalLogFile as [@LogicalLogFile]
, @PhysicalDataFile as [@PhysicalDataFile]
, @PhysicalLogFile as [@PhysicalLogFile]

Note: This is the revised version. Thanks to steveh99999 for gently pointing out I was using a deprecated system table. A nice side effect is that there’s no need for dynamic SQL either.

 

Better dependency checking

The dependency information in SQL Server has always been a bit shaky. It’s a hard problem for them to solve. Meanwhile, I think you can do a lot worse than simply search the ‘source code’ of the objects in the database. That way you can even search for things that aren’t proper objects, such as column names or in fact any string at all. All you need are two fairly simple stored procedures in your master database.

if exists (	select 	1 
		from 	dbo.sysobjects 
		where 	id = object_id(N'dbo.dba_depends') 
			and objectproperty(id, N'IsProcedure') = 1    )
	drop procedure dbo.dba_depends
go

create proc dbo.dba_depends
(
	@SearchTerm		varchar(255)
	, @IncludeSystemDBs	bit = 0
)
as

/*
-------------------------------------------------------------------------------
Version  : 1.5
Date     : 07/11/2007
Comments :	syscomments.xtype
		-----------------
		C = CHECK constraint
		D = Default or DEFAULT constraint
		F = FOREIGN KEY constraint
		L = Log
		FN = Scalar function
		IF = Inlined table-function
		P = Stored procedure
		PK = PRIMARY KEY constraint (type is K)
		RF = Replication filter stored procedure 
		S = System table
		TF = Table function
		TR = Trigger
		U = User table
		UQ = UNIQUE constraint (type is K)
		V = View
		X = Extended stored procedure
-------------------------------------------------------------------------------
*/

declare @DBName		varchar(128)
	, @SearchThisDB	bit

create table #t
(
	DBName		varchar(128)	null
	, ObjectName	sysname		null
	, ObjectXType	char(2)		null
)


declare db_cursor cursor
local forward_only 
for 
select	[name]
from	sys.databases
where	state = 0 --ONLINE
order by name


open db_cursor

	fetch	next 
	from	db_cursor 
	into 	@DBName

	while @@fetch_status = 0
	begin

		set @SearchThisDB = 1

		if @IncludeSystemDBs = 0 and lower(@DBName) in ('master','tempdb','model','msdb','reportserver','reportservertempdb')
			set @SearchThisDB = 0

		if @SearchThisDB = 1
			exec master.dbo.dba_depends_inner @SearchTerm, @DBName

		fetch	next 
		from	db_cursor 
		into 	@DBName

	end

close db_cursor
deallocate db_cursor




select	distinct
	DBName
	, case
		when ObjectXType = 'FN' then 'Function'
		when ObjectXType = 'P' then 'Stored Procedure'
		when ObjectXType = 'IF' then 'Inlined table-function'
		when ObjectXType = 'TF' then 'Table function'
		when ObjectXType = 'TR' then 'Trigger'
		when ObjectXType = 'V' then 'View'
		when ObjectXType = 'X' then 'Extended stored procedure'
		when ObjectXType = 'U' then 'Table'
		else ObjectXType
	end as ObjectType
	, ObjectName
	, ObjectXType
from	#t
order by 1,2,3


drop table #t


go




if exists (	select 	1 
		from 	dbo.sysobjects 
		where 	id = object_id(N'dbo.dba_depends_inner') 
			and objectproperty(id, N'IsProcedure') = 1    )
	drop procedure dbo.dba_depends_inner
go

create proc dbo.dba_depends_inner
(
	@SearchTerm 	varchar(255)
	, @DBName	varchar(128)
)
as

/*
-------------------------------------------------------------------------------
Version  : 1.3
Date     : 12/03/2007
-------------------------------------------------------------------------------
*/

set nocount on

declare @SQL nvarchar(500)

--print ''
--print ''
--print 'database: ' + @DBName



set @SQL = 'use [' + @DBName + '] ' +
'insert	#t
	(DBName
	, ObjectName
	, ObjectXType)
select 	''' + @DBName +
'''	, so.[name]
	, so.xtype
from 	syscomments sc  
	inner join sysobjects so on so.[id] = sc.[id]
where 	so.xtype in (''FN'', ''P'', ''IF'', ''TF'', ''TR'', ''V'', ''X'')
	and sc.[text] like ''%' + @SearchTerm + '%''
order by sc.[id], sc.colid'

--print @SQL

exec sp_executesql @sql



set @SQL = 'use [' + @DBName + '] ' +
'insert	#t
	(DBName
	, ObjectName
	, ObjectXType)
select 	''' + @DBName +
'''	, obj.name + ''.'' + col.name
	, ''U''
from	sysobjects obj
	inner join syscolumns col
	on obj.id = col.id
where	obj.xtype in (''U'')
	and col.name like ''%' + @SearchTerm + '%'''

--print @SQL

exec sp_executesql @sql

set nocount off

go